push sheeet

pkgs/tools/X11/libstrangle/default.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  fetchpatch,
+  libGL,
+  libX11,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libstrangle";
+  version = "unstable-202202022";
+
+  buildInputs = [
+    libGL
+    libX11
+  ];
+
+  src = fetchFromGitLab {
+    owner = "torkel104";
+    repo = pname;
+    rev = "0273e318e3b0cc759155db8729ad74266b74cb9b";
+    hash = "sha256-h10QA7m7hIQHq1g/vCYuZsFR2NVbtWBB46V6OWP5wgM=";
+  };
+
+  makeFlags = [
+    "prefix="
+    "DESTDIR=$(out)"
+  ];
+
+  patches = [
+    ./nixos.patch
+    # Pull the fix pending upstream inclusion for gcc-13:
+    #   https://gitlab.com/torkel104/libstrangle/-/merge_requests/29
+    (fetchpatch {
+      name = "gcc-13.patch";
+      url = "https://gitlab.com/torkel104/libstrangle/-/commit/4e17025071de1d99630febe7270b4f63056d0dfa.patch";
+      hash = "sha256-AKMHAZhCPcn62pi4fBGhw2r8SNSkCDMUCpR3IlmJ7wQ=";
+    })
+  ];
+
+  postPatch = ''
+    substituteAllInPlace src/strangle.sh
+    substituteAllInPlace src/stranglevk.sh
+  '';
+  postInstall = ''
+    substitute $out/share/vulkan/implicit_layer.d/libstrangle_vk.json $out/share/vulkan/implicit_layer.d/libstrangle_vk.x86.json \
+      --replace "libstrangle_vk.so" "$out/lib/libstrangle/lib32/libstrangle_vk.so"
+    substituteInPlace $out/share/vulkan/implicit_layer.d/libstrangle_vk.json \
+      --replace "libstrangle_vk.so" "$out/lib/libstrangle/lib64/libstrangle_vk.so"
+  '';
+
+  meta = with lib; {
+    homepage = "https://gitlab.com/torkel104/libstrangle";
+    description = "Frame rate limiter for Linux/OpenGL";
+    license = licenses.gpl3;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ aske ];
+    mainProgram = "strangle";
+  };
+}

pkgs/tools/X11/libstrangle/nixos.patch

@@ -0,0 +1,43 @@
+diff --git a/makefile b/makefile
+--- a/makefile
++++ b/makefile
+@@ -86,10 +86,6 @@ install-common:
+ 	install -m 0755 -D -T $(SOURCEDIR)/stranglevk.sh $(DESTDIR)$(bindir)/stranglevk
+ 	install -m 0644 -D -T $(SOURCEDIR)/vulkan/libstrangle_vk.json $(DESTDIR)$(datarootdir)/vulkan/implicit_layer.d/libstrangle_vk.json
+ 
+-install-ld: ld
+-	install -m 0644 -D -T $(BUILDDIR)/libstrangle.conf $(DESTDIR)/etc/ld.so.conf.d/libstrangle.conf
+-	if [ -z "$(DESTDIR)" ]; then ldconfig; fi
+-
+ install-32: 32-bit
+ 	install -m 0755 -D -T $(BUILDDIR)/libstrangle32.so $(DESTDIR)$(LIB32_PATH)/libstrangle.so
+ 	install -m 0755 -D -T $(BUILDDIR)/libstrangle32_nodlsym.so $(DESTDIR)$(LIB32_PATH)/libstrangle_nodlsym.so
+@@ -109,8 +105,7 @@ install: \
+ 	all \
+ 	install-common \
+ 	install-32 \
+-	install-64 \
+-	install-ld
++	install-64
+ 
+ clean:
+ 	rm -f $(BUILDDIR)/libstrangle64.so
+diff --git a/src/strangle.sh b/src/strangle.sh
+--- a/src/strangle.sh
++++ b/src/strangle.sh
+@@ -130,6 +130,5 @@ if [ "$STRANGLE_VKONLY" != "1" ]; then
+ 	fi
+ fi
+ 
+-# Execute the strangled program under a clean environment
+ # pass through the FPS and overriden LD_PRELOAD environment variables
+-exec env ENABLE_VK_LAYER_TORKEL104_libstrangle=1 LD_PRELOAD="${LD_PRELOAD}" "$@"
++ENABLE_VK_LAYER_TORKEL104_libstrangle=1 XDG_DATA_DIRS="${XDG_DATA_DIRS}${XDG_DATA_DIRS:+:}@out@/share" LD_LIBRARY_PATH="${LD_LIBRARY_PATH}${LD_LIBRARY_PATH:+:}@out@/lib/libstrangle/lib64:@out@/lib/libstrangle/lib32" LD_PRELOAD="${LD_PRELOAD}" exec "$@"
+diff --git a/src/stranglevk.sh b/src/stranglevk.sh
+--- a/src/stranglevk.sh
++++ b/src/stranglevk.sh
+@@ -1,3 +1,3 @@
+ #!/bin/sh
+
+-ENABLE_VK_LAYER_TORKEL104_libstrangle=1 STRANGLE_VKONLY=1 strangle "$@"
++ENABLE_VK_LAYER_TORKEL104_libstrangle=1 STRANGLE_VKONLY=1 @out@/bin/strangle "$@"