push sheeet

pkgs/tools/admin/ibmcloud-cli/default.nix

@@ -0,0 +1,84 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  installShellFiles,
+  writableTmpDirAsHomeHook,
+}:
+let
+  arch =
+    with stdenv.hostPlatform;
+    if isx86_64 then
+      "amd64"
+    else if isAarch64 then
+      "arm64"
+    else if isi686 then
+      "386"
+    else if isPower64 && isLittleEndian then
+      "ppc64le"
+    else if isS390x then
+      "s390x"
+    else
+      throw "Unsupported arch: ${stdenv.hostPlatform.system}";
+  platform =
+    if stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64 then
+      "macos_arm64"
+    else if stdenv.hostPlatform.isDarwin then
+      "macos"
+    else
+      "linux_${arch}";
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "ibmcloud-cli";
+  version = "2.36.0";
+
+  src = fetchurl {
+    url = "https://download.clis.cloud.ibm.com/ibm-cloud-cli/${finalAttrs.version}/binaries/IBM_Cloud_CLI_${finalAttrs.version}_${platform}.tgz";
+    hash =
+      {
+        "x86_64-darwin" = "sha256-hIHFfUxAhpA+YIN7Bq65khFFj+3BCuYRtMq2WjQwqYQ=";
+        "aarch64-darwin" = "sha256-ZZ500RWagqhf63zwiQpV8y+gtCxGfbA36F97x67coUE=";
+        "x86_64-linux" = "sha256-+ZKlFvrDPm3ERq8/r7cjgsJWjUr8+sGFqYXdiSUPeXo=";
+        "aarch64-linux" = "sha256-ER/Ey3Jux3i8tC30/65awHdEd6efscUVjX/bFAk1b7c=";
+        "i686-linux" = "sha256-5A0kUegKVHSTZ+jRg5+07wvV4PkCvOPddvyC1ZLCbmI=";
+        "powerpc64le-linux" = "sha256-XcHrdA9i3Euc0yIjUtFrmIFMJi+onXRK+tHzNxmQwHg=";
+        "s390x-linux" = "sha256-loGQxvUqp9ngieVOVuZ6IhOKgyrVGBd+y9LdZtKEPwc=";
+      }
+      .${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
+  };
+
+  nativeBuildInputs = [
+    installShellFiles
+    writableTmpDirAsHomeHook
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 ibmcloud $out/bin/ibmcloud
+    mkdir -p $out/share/ibmcloud
+    cp LICENSE NOTICE $out/share/ibmcloud
+    installShellCompletion --cmd ibmcloud --bash <($out/bin/ibmcloud --generate-bash-completion)
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = ./update.sh;
+
+  meta = {
+    description = "Command line client for IBM Cloud";
+    homepage = "https://cloud.ibm.com/docs/cli";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ emilytrau ];
+    platforms = [
+      "x86_64-linux"
+      "aarch64-linux"
+      "i686-linux"
+      "powerpc64le-linux"
+      "s390x-linux"
+    ]
+    ++ lib.platforms.darwin;
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    mainProgram = "ibmcloud";
+  };
+})

pkgs/tools/admin/ibmcloud-cli/update.sh

@@ -0,0 +1,29 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p bash nix-update common-updater-scripts nix jq
+
+set -euo pipefail
+
+currentVersion=$(nix-instantiate --eval -E "with import ./. {}; ibmcloud-cli.version or (lib.getVersion ibmcloud-cli)" | tr -d '"')
+latestVersion=$(curl ${GITHUB_TOKEN:+-u ":$GITHUB_TOKEN"} -sL https://api.github.com/repos/IBM-Cloud/ibm-cloud-cli-release/releases/latest | jq --raw-output .tag_name | sed 's/^v//')
+
+if [[ "$currentVersion" == "$latestVersion" ]]; then
+    echo "package is up-to-date: $currentVersion"
+    exit 0
+fi
+
+update-source-version ibmcloud-cli $latestVersion || true
+
+for system in \
+    x86_64-linux \
+    aarch64-linux \
+    i686-linux \
+    powerpc64le-linux \
+    s390x-linux \
+    x86_64-darwin \
+    aarch64-darwin; do
+    tmp=$(mktemp -d)
+    curl -fsSL -o $tmp/ibmcloud-cli $(nix-instantiate --eval -E "with import ./. {}; ibmcloud-cli.src.url" --system "$system" | tr -d '"')
+    hash=$(nix --extra-experimental-features nix-command hash file $tmp/ibmcloud-cli)
+    update-source-version ibmcloud-cli $latestVersion $hash --system=$system --ignore-same-version
+    rm -rf $tmp
+done