push sheeet

pkgs/tools/misc/dvtm/default.nix

@@ -0,0 +1,19 @@
+{ callPackage, fetchurl }:
+callPackage ./dvtm.nix rec {
+  pname = "dvtm";
+  version = "0.15";
+
+  src = fetchurl {
+    url = "https://www.brain-dump.org/projects/dvtm/dvtm-${version}.tar.gz";
+    sha256 = "0475w514b7i3gxk6khy8pfj2gx9l7lv2pwacmq92zn1abv01a84g";
+  };
+
+  patches = [
+    # https://github.com/martanne/dvtm/pull/69
+    # Use self-pipe instead of signal blocking fixes issues on darwin.
+    (fetchurl {
+      url = "https://github.com/martanne/dvtm/commit/1f1ed664d64603f3f1ce1388571227dc723901b2.patch";
+      sha256 = "1cby8x3ckvhzqa8yxlfrwzgm8wk7yz84kr9psdjr7xwpnca1cqrd";
+    })
+  ];
+}

pkgs/tools/misc/dvtm/dvtm.nix

@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  ncurses,
+  customConfig ? null,
+  pname,
+  version,
+  src,
+  patches ? [ ],
+}:
+stdenv.mkDerivation {
+
+  inherit
+    pname
+    version
+    src
+    patches
+    ;
+
+  CFLAGS = lib.optionalString stdenv.hostPlatform.isDarwin "-D_DARWIN_C_SOURCE";
+
+  postPatch = lib.optionalString (customConfig != null) ''
+    cp ${builtins.toFile "config.h" customConfig} ./config.h
+  '';
+
+  nativeBuildInputs = [ ncurses ];
+  buildInputs = [ ncurses ];
+
+  prePatch = ''
+    substituteInPlace Makefile \
+      --replace /usr/share/terminfo $out/share/terminfo
+  '';
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "Dynamic virtual terminal manager";
+    homepage = "http://www.brain-dump.org/projects/dvtm";
+    license = licenses.mit;
+    maintainers = [ ];
+    platforms = platforms.unix;
+  };
+}

pkgs/tools/misc/dvtm/unstable.nix

@@ -0,0 +1,31 @@
+{
+  callPackage,
+  fetchpatch,
+  fetchzip,
+}:
+
+let
+  rev = "7bcf43f8dbd5c4a67ec573a1248114caa75fa3c2";
+in
+callPackage ./dvtm.nix {
+  pname = "dvtm-unstable";
+  version = "unstable-2021-03-09";
+
+  src = fetchzip {
+    urls = [
+      "https://github.com/martanne/dvtm/archive/${rev}.tar.gz"
+      "https://git.sr.ht/~martanne/dvtm/archive/${rev}.tar.gz"
+    ];
+    hash = "sha256-UtkNsW0mvLfbPSAIIZ1yvX9xzIDtiBeXCjhN2R8JhDc=";
+  };
+
+  patches = [
+    # https://github.com/martanne/dvtm/pull/69
+    # Use self-pipe instead of signal blocking fixes issues on darwin.
+    (fetchpatch {
+      name = "use-self-pipe-fix-darwin";
+      url = "https://github.com/martanne/dvtm/commit/1f1ed664d64603f3f1ce1388571227dc723901b2.patch";
+      sha256 = "14j3kks7b1v6qq12442v1da3h7khp02rp0vi0qrz0rfgkg1zilpb";
+    })
+  ];
+}