push sheeet

pkgs/tools/text/mecab/base.nix

@@ -0,0 +1,23 @@
+{ fetchurl, libiconv }:
+
+finalAttrs: {
+  version = "0.996";
+
+  src = fetchurl {
+    url = "https://drive.google.com/uc?export=download&id=0B4y35FiV1wh7cENtOXlicTFaRUE";
+    name = "mecab-${finalAttrs.version}.tar.gz";
+    hash = "sha256-4HMyV4MTW3LmZhRceBu0j62lg9UiT7JJD7bBQDumnFk=";
+  };
+
+  buildInputs = [ libiconv ];
+
+  configureFlags = [
+    "--with-charset=utf8"
+  ];
+
+  # mecab uses several features that have been removed in C++17.
+  # Force the language mode to C++14, so that it can compile with clang 16.
+  makeFlags = [ "CXXFLAGS=-std=c++14" ];
+
+  doCheck = true;
+}

pkgs/tools/text/mecab/default.nix

@@ -0,0 +1,34 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  mecab-ipadic,
+  libiconv,
+}:
+
+let
+  mecab-base = import ./base.nix { inherit fetchurl libiconv; };
+in
+stdenv.mkDerivation (
+  finalAttrs:
+  (
+    (mecab-base finalAttrs)
+    // {
+      pname = "mecab";
+
+      postInstall = ''
+        mkdir -p $out/lib/mecab/dic
+        ln -s ${mecab-ipadic} $out/lib/mecab/dic/ipadic
+      '';
+
+      meta = with lib; {
+        description = "Japanese morphological analysis system";
+        homepage = "http://taku910.github.io/mecab";
+        license = licenses.bsd3;
+        platforms = platforms.unix;
+        mainProgram = "mecab";
+        maintainers = with maintainers; [ auntie ];
+      };
+    }
+  )
+)

pkgs/tools/text/mecab/ipadic.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  mecab-nodic,
+  buildPackages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "mecab-ipadic";
+  version = "2.7.0-20070801";
+
+  src = fetchurl {
+    url = "https://drive.google.com/uc?export=download&id=0B4y35FiV1wh7MWVlSDBCSXZMTXM";
+    name = "mecab-ipadic-${finalAttrs.version}.tar.gz";
+    hash = "sha256-ti9SfYgcUEV2uu2cbvZWFVRlixdc5q4AlqYDB+SeNSM=";
+  };
+
+  buildInputs = [ mecab-nodic ];
+
+  configureFlags = [
+    "--with-charset=utf8"
+    "--with-dicdir=${placeholder "out"}"
+  ]
+  ++ lib.optionals (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
+    "--with-mecab-config=${lib.getExe' buildPackages.mecab "mecab-config"}"
+  ]
+  ++ lib.optionals (stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
+    "--with-mecab-config=${lib.getExe' (lib.getDev mecab-nodic) "mecab-config"}"
+  ];
+})

pkgs/tools/text/mecab/nodic.nix

@@ -0,0 +1,18 @@
+{
+  stdenv,
+  fetchurl,
+  libiconv,
+}:
+
+let
+  mecab-base = import ./base.nix { inherit fetchurl libiconv; };
+in
+stdenv.mkDerivation (
+  finalAttrs:
+  (
+    (mecab-base finalAttrs)
+    // {
+      pname = "mecab-nodic";
+    }
+  )
+)