push sheeet

pkgs/tools/text/multitran/data/default.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+# This package requires a locale ru_RU.cp1251 locale entry.
+# Waiting for a better idea, I created it modifying a store file using:
+#   localedef -f CP1251 -i ru_RU ru_RU.CP1251
+# The store file mentioned is in "${glibc.out}/lib/locale/locale-archive"
+
+stdenv.mkDerivation {
+  pname = "multitran-data";
+  version = "0.3";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/multitran/multitran-data.tar.bz2";
+    sha256 = "9c2ff5027c2fe72b0cdf056311cd7543f447feb02b455982f20d4a3966b7828c";
+  };
+
+  patchPhase = ''
+    sed -i -e 's@\$(DESTDIR)/usr@'$out'@' Makefile
+  '';
+
+  meta = {
+    homepage = "https://multitran.sourceforge.net/";
+    description = "Multitran data english-russian";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/tools/text/multitran/libbtree/default.nix

@@ -0,0 +1,25 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libbtree";
+  version = "0.0.1alpha2";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/multitran/libbtree-${version}.tar.bz2";
+    sha256 = "34a584e45058950337ff9342693b6739b52c3ce17e66440526c4bd6f9575802c";
+  };
+  patchPhase = ''
+    sed -i -e 's@\$(DESTDIR)/usr@'$out'@' src/Makefile;
+  '';
+
+  meta = {
+    homepage = "https://multitran.sourceforge.net/";
+    description = "Multitran lib: library for reading Multitran's BTREE database format";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/tools/text/multitran/libfacet/default.nix

@@ -0,0 +1,31 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libmtsupport,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libfacet";
+  version = "0.0.1alpha2";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/multitran/libfacet-${version}.tar.bz2";
+    sha256 = "dc53351c4035a3c27dc6c1d0410e808346fbc107e7e7c112ec65c59d0df7a144";
+  };
+
+  buildInputs = [ libmtsupport ];
+
+  patchPhase = ''
+    sed -i -e 's@\$(DESTDIR)/usr@'$out'@' \
+      -e 's@/usr/include/mt/support@${libmtsupport}/include/mt/support@' \
+      src/Makefile;
+  '';
+
+  meta = {
+    homepage = "https://multitran.sourceforge.net/";
+    description = "Multitran lib: enchanced locale facets";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/tools/text/multitran/libmtquery/default.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libmtsupport,
+  libfacet,
+  libbtree,
+  multitrandata,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libmtquery";
+  version = "0.0.1alpha3";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/multitran/libmtquery-${version}.tar.bz2";
+    sha256 = "e24c7c15772445f1b14871928d84dd03cf93bd88f9d2b2ed1bf0257c2cf2b15e";
+  };
+
+  buildInputs = [
+    libmtsupport
+    libfacet
+    libbtree
+    multitrandata
+  ];
+
+  NIX_LDFLAGS = "-lbtree";
+
+  patchPhase = ''
+    sed -i -e 's@\$(DESTDIR)/usr@'$out'@' \
+      -e 's@/usr/include/mt/support@${libmtsupport}/include/mt/support@' \
+      -e 's@/usr/include/btree@${libbtree}/include/btree@' \
+      -e 's@/usr/include/facet@${libfacet}/include/facet@' \
+      src/Makefile testsuite/Makefile;
+    sed -i -e 's@/usr/share/multitran@${multitrandata}/share/multitran@' src/config.cc
+  '';
+
+  meta = {
+    homepage = "https://multitran.sourceforge.net/";
+    description = "Multitran lib: main engine to query translations";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/tools/text/multitran/libmtsupport/default.nix

@@ -0,0 +1,25 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libmtsupport";
+  version = "0.0.1alpha2";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/multitran/libmtsupport-${version}.tar.bz2";
+    sha256 = "481f0f1ec15d7274f1e4eb93e7d060df10a181efd037eeff5e8056d283a9298b";
+  };
+  patchPhase = ''
+    sed -i -e 's@\$(DESTDIR)/usr@'$out'@' src/Makefile;
+  '';
+
+  meta = {
+    homepage = "https://multitran.sourceforge.net/";
+    description = "Multitran lib: basic useful functions";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/tools/text/multitran/mtutils/default.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  libmtsupport,
+  libfacet,
+  libbtree,
+  libmtquery,
+  help2man,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "mt-utils";
+  version = "0.0.1alpha3";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/multitran/mt-utils-${version}.tar.bz2";
+    sha256 = "e407702c90c5272882386914e1eeca5f6c5039393af9a44538536b94867b0a0e";
+  };
+
+  buildInputs = [
+    libmtsupport
+    libfacet
+    libbtree
+    libmtquery
+    help2man
+  ];
+
+  patchPhase = ''
+    sed -i -e 's@\$(DESTDIR)/usr@'$out'@' \
+      -e 's@/usr/include/mt/support@${libmtsupport}/include/mt/support@' \
+      -e 's@/usr/include/btree@${libbtree}/include/btree@' \
+      -e 's@/usr/include/facet@${libfacet}/include/facet@' \
+      -e 's@/usr/include/mt/query@${libmtquery}/include/mt/query@' \
+      -e 's@-lmtquery@-lmtquery -lmtsupport -lfacet@' \
+      src/Makefile;
+    # Fixing multibyte locale output
+    sed -i -e 's@message.length()@message.length()*5@' \
+      src/converter.cc;
+  '';
+
+  meta = {
+    homepage = "https://multitran.sourceforge.net/";
+    description = "Multitran: simple command line utilities for dictionary maintenance";
+    mainProgram = "mtquery";
+    license = lib.licenses.gpl2Only;
+    maintainers = [ ];
+    platforms = with lib.platforms; linux;
+  };
+}