646b892680
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s
55 lines
1.5 KiB
Nix
55 lines
1.5 KiB
Nix
{
|
|
ffmpeg_7-full,
|
|
fetchFromGitHub,
|
|
fetchpatch2,
|
|
lib,
|
|
}:
|
|
|
|
let
|
|
version = "7.1.2-1";
|
|
in
|
|
|
|
(ffmpeg_7-full.override {
|
|
inherit version; # Important! This sets the ABI.
|
|
source = fetchFromGitHub {
|
|
owner = "jellyfin";
|
|
repo = "jellyfin-ffmpeg";
|
|
rev = "v${version}";
|
|
hash = "sha256-1nisdEtH5J5cDqUeDev0baCHopmoQ1SEojFdYdYeY0Q=";
|
|
};
|
|
}).overrideAttrs
|
|
(old: {
|
|
pname = "jellyfin-ffmpeg";
|
|
|
|
configureFlags = old.configureFlags ++ [
|
|
"--extra-version=Jellyfin"
|
|
"--disable-ptx-compression" # https://github.com/jellyfin/jellyfin/issues/7944#issuecomment-1156880067
|
|
];
|
|
|
|
# Clobber upstream patches as they don't apply to the Jellyfin fork
|
|
patches = [
|
|
(fetchpatch2 {
|
|
name = "lcevcdec-4.0.0-compat.patch";
|
|
url = "https://code.ffmpeg.org/FFmpeg/FFmpeg/commit/fa23202cc7baab899894e8d22d82851a84967848.patch";
|
|
hash = "sha256-Ixkf1xzuDGk5t8J/apXKtghY0X9cfqSj/q987zrUuLQ=";
|
|
})
|
|
];
|
|
|
|
postPatch = ''
|
|
for file in $(cat debian/patches/series); do
|
|
patch -p1 < debian/patches/$file
|
|
done
|
|
|
|
${old.postPatch or ""}
|
|
'';
|
|
|
|
meta = {
|
|
inherit (old.meta) license mainProgram;
|
|
changelog = "https://github.com/jellyfin/jellyfin-ffmpeg/releases/tag/v${version}";
|
|
description = "${old.meta.description} (Jellyfin fork)";
|
|
homepage = "https://github.com/jellyfin/jellyfin-ffmpeg";
|
|
maintainers = with lib.maintainers; [ justinas ];
|
|
pkgConfigModules = [ "libavutil" ];
|
|
};
|
|
})
|