646b892680
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s
93 lines
2.6 KiB
Nix
93 lines
2.6 KiB
Nix
{
|
|
lib,
|
|
stdenvNoCC,
|
|
fetchFromGitHub,
|
|
buildDotnetModule,
|
|
buildNpmPackage,
|
|
dotnetCorePackages,
|
|
nixosTests,
|
|
}:
|
|
|
|
stdenvNoCC.mkDerivation (finalAttrs: {
|
|
pname = "kavita";
|
|
version = "0.8.7";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "kareadita";
|
|
repo = "kavita";
|
|
rev = "v${finalAttrs.version}";
|
|
hash = "sha256-jRP7ts6+jogPdmP+DfzeijlG70kvJWgf8da/sTBT9d4=";
|
|
};
|
|
|
|
backend = buildDotnetModule {
|
|
pname = "kavita-backend";
|
|
inherit (finalAttrs) version src;
|
|
|
|
patches = [
|
|
# The webroot is hardcoded as ./wwwroot
|
|
./change-webroot.diff
|
|
# NOTE: Upstream frequently removes old database migrations between versions.
|
|
# Currently no migration patches are needed for upgrades from NixOS 24.11 (v0.8.3.2).
|
|
# Future updates should check if migration restoration is needed for supported upgrade paths.
|
|
];
|
|
postPatch = ''
|
|
substituteInPlace API/Services/DirectoryService.cs --subst-var out
|
|
|
|
substituteInPlace API/Startup.cs API/Services/LocalizationService.cs API/Controllers/FallbackController.cs \
|
|
--subst-var-by webroot "${finalAttrs.frontend}/lib/node_modules/kavita-webui/dist/browser"
|
|
'';
|
|
|
|
executables = [ "API" ];
|
|
|
|
projectFile = "API/API.csproj";
|
|
nugetDeps = ./nuget-deps.json;
|
|
dotnet-sdk = dotnetCorePackages.sdk_9_0;
|
|
dotnet-runtime = dotnetCorePackages.aspnetcore_9_0;
|
|
};
|
|
|
|
frontend = buildNpmPackage {
|
|
pname = "kavita-frontend";
|
|
inherit (finalAttrs) version src;
|
|
|
|
sourceRoot = "${finalAttrs.src.name}/UI/Web";
|
|
|
|
npmBuildScript = "prod";
|
|
npmFlags = [ "--legacy-peer-deps" ];
|
|
npmRebuildFlags = [ "--ignore-scripts" ]; # Prevent playwright from trying to install browsers
|
|
npmDepsHash = "sha256-/fBUOlZfNGyRu9mfniSMBKHPNgNsZNpbFZpVrFwBtb4=";
|
|
};
|
|
|
|
dontBuild = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/bin $out/lib/kavita
|
|
ln -s $backend/lib/kavita-backend $out/lib/kavita/backend
|
|
ln -s $frontend/lib/node_modules/kavita-webui/dist $out/lib/kavita/frontend
|
|
ln -s $backend/bin/API $out/bin/kavita
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru = {
|
|
tests = {
|
|
inherit (nixosTests) kavita;
|
|
};
|
|
updateScript = ./update.sh;
|
|
};
|
|
|
|
meta = {
|
|
description = "Fast, feature rich, cross platform reading server";
|
|
homepage = "https://kavitareader.com";
|
|
changelog = "https://github.com/kareadita/kavita/releases/tag/${finalAttrs.src.rev}";
|
|
license = lib.licenses.gpl3Only;
|
|
platforms = lib.platforms.linux;
|
|
maintainers = with lib.maintainers; [
|
|
misterio77
|
|
nevivurn
|
|
];
|
|
mainProgram = "kavita";
|
|
};
|
|
})
|