646b892680
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s
113 lines
2.9 KiB
Nix
113 lines
2.9 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
appimageTools,
|
|
fetchurl,
|
|
makeWrapper,
|
|
_7zz,
|
|
}:
|
|
|
|
let
|
|
pname = "notesnook";
|
|
version = "3.2.4";
|
|
|
|
inherit (stdenv.hostPlatform) system;
|
|
throwSystem = throw "Unsupported system: ${system}";
|
|
|
|
suffix =
|
|
{
|
|
x86_64-linux = "linux_x86_64.AppImage";
|
|
aarch64-linux = "linux_arm64.AppImage";
|
|
x86_64-darwin = "mac_x64.dmg";
|
|
aarch64-darwin = "mac_arm64.dmg";
|
|
}
|
|
.${system} or throwSystem;
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/streetwriters/notesnook/releases/download/v${version}/notesnook_${suffix}";
|
|
hash =
|
|
{
|
|
x86_64-linux = "sha256-n4yDBaDq09idmjRZ+y2zT7rZcI4wsDhMidx9sNox5cM=";
|
|
aarch64-linux = "sha256-UQFySvvs+paCzt2XSrbYiChEQJIbef3rCOST1r+zZx8=";
|
|
x86_64-darwin = "sha256-42US8m6ZbGTUNkU0p4y0pgXKiSsjZZHlQhwv2/LDlO4=";
|
|
aarch64-darwin = "sha256-eJVyuL5nBGMr8WhOK4NOMNSMYBASQZbsbLPLgug7ZNs=";
|
|
}
|
|
.${system} or throwSystem;
|
|
};
|
|
|
|
appimageContents = appimageTools.extractType2 {
|
|
inherit pname version src;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Fully open source & end-to-end encrypted note taking alternative to Evernote";
|
|
longDescription = ''
|
|
Notesnook is a free (as in speech) & open source note taking app
|
|
focused on user privacy & ease of use. To ensure zero knowledge
|
|
principles, Notesnook encrypts everything on your device using
|
|
XChaCha20-Poly1305 & Argon2.
|
|
'';
|
|
homepage = "https://notesnook.com";
|
|
license = licenses.gpl3Only;
|
|
maintainers = with maintainers; [
|
|
cig0
|
|
j0lol
|
|
];
|
|
platforms = [
|
|
"x86_64-linux"
|
|
"aarch64-linux"
|
|
"x86_64-darwin"
|
|
"aarch64-darwin"
|
|
];
|
|
mainProgram = "notesnook";
|
|
};
|
|
|
|
linux = appimageTools.wrapType2 rec {
|
|
inherit
|
|
pname
|
|
version
|
|
src
|
|
meta
|
|
;
|
|
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
profile = ''
|
|
export LC_ALL=C.UTF-8
|
|
'';
|
|
|
|
extraInstallCommands = ''
|
|
wrapProgram $out/bin/notesnook \
|
|
--add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}"
|
|
install -Dm444 ${appimageContents}/notesnook.desktop -t $out/share/applications
|
|
install -Dm444 ${appimageContents}/notesnook.png -t $out/share/pixmaps
|
|
substituteInPlace $out/share/applications/notesnook.desktop \
|
|
--replace 'Exec=AppRun --no-sandbox %U' 'Exec=${pname}'
|
|
'';
|
|
};
|
|
|
|
darwin = stdenv.mkDerivation {
|
|
inherit
|
|
pname
|
|
version
|
|
src
|
|
meta
|
|
;
|
|
|
|
nativeBuildInputs = [ _7zz ];
|
|
|
|
sourceRoot = "Notesnook.app";
|
|
|
|
# 7zz did not unpack in setup hook for some reason, done manually here
|
|
unpackPhase = ''
|
|
7zz x $src
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/Applications/Notesnook.app
|
|
cp -R . $out/Applications/Notesnook.app
|
|
'';
|
|
};
|
|
in
|
|
if stdenv.hostPlatform.isDarwin then darwin else linux
|