646b892680
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s
105 lines
2.2 KiB
Nix
105 lines
2.2 KiB
Nix
{
|
|
lib,
|
|
fetchFromGitHub,
|
|
python3,
|
|
writeText,
|
|
writeShellScript,
|
|
sqlite,
|
|
nixosTests,
|
|
}:
|
|
let
|
|
pypkgs = python3.pkgs;
|
|
|
|
dbSql = writeText "create_pykms_db.sql" ''
|
|
CREATE TABLE clients(
|
|
clientMachineId TEXT,
|
|
machineName TEXT,
|
|
applicationId TEXT,
|
|
skuId TEXT,
|
|
licenseStatus TEXT,
|
|
lastRequestTime INTEGER,
|
|
kmsEpid TEXT,
|
|
requestCount INTEGER
|
|
);
|
|
'';
|
|
|
|
dbScript = writeShellScript "create_pykms_db.sh" ''
|
|
set -eEuo pipefail
|
|
|
|
db=''${1:-/var/lib/pykms/clients.db}
|
|
|
|
if [ ! -e $db ] ; then
|
|
${lib.getBin sqlite}/bin/sqlite3 $db < ${dbSql}
|
|
fi
|
|
'';
|
|
|
|
in
|
|
pypkgs.buildPythonApplication rec {
|
|
pname = "pykms";
|
|
version = "0-unstable-2024-07-06";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Py-KMS-Organization";
|
|
repo = "py-kms";
|
|
rev = "465f4d14c728819d4eb00e3419bd1cb98af7f81c";
|
|
hash = "sha256-/XbMbcBcZPO7joHyaprJ29Cq4gNpuuzTzj2x1XDIyj8=";
|
|
};
|
|
|
|
sourceRoot = "${src.name}/py-kms";
|
|
|
|
propagatedBuildInputs = with pypkgs; [
|
|
systemd
|
|
pytz
|
|
tzlocal
|
|
dnspython
|
|
];
|
|
|
|
postPatch = ''
|
|
siteDir=$out/${python3.sitePackages}
|
|
|
|
substituteInPlace pykms_DB2Dict.py \
|
|
--replace "'KmsDataBase.xml'" "'$siteDir/KmsDataBase.xml'"
|
|
'';
|
|
|
|
format = "other";
|
|
|
|
# there are no tests
|
|
doCheck = false;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $siteDir
|
|
|
|
PYTHONPATH="$PYTHONPATH:$siteDir"
|
|
|
|
mv * $siteDir
|
|
for b in Client Server ; do
|
|
makeWrapper ${python3.interpreter} $out/bin/''${b,,} \
|
|
--argv0 pykms-''${b,,} \
|
|
--add-flags $siteDir/pykms_$b.py \
|
|
--set PYTHONPATH $PYTHONPATH
|
|
done
|
|
|
|
install -Dm755 ${dbScript} $out/libexec/create_pykms_db.sh
|
|
|
|
install -Dm644 ../README.md -t $out/share/doc/pykms
|
|
|
|
${python3.interpreter} -m compileall $siteDir
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru.tests = { inherit (nixosTests) pykms; };
|
|
|
|
meta = with lib; {
|
|
description = "Windows KMS (Key Management Service) server written in Python";
|
|
homepage = "https://github.com/Py-KMS-Organization/py-kms";
|
|
license = licenses.unlicense;
|
|
maintainers = with maintainers; [
|
|
peterhoeg
|
|
zopieux
|
|
];
|
|
};
|
|
}
|