646b892680
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s
95 lines
2.6 KiB
Nix
95 lines
2.6 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
buildGoModule,
|
|
fetchFromGitHub,
|
|
installShellFiles,
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "syft";
|
|
version = "1.33.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "anchore";
|
|
repo = "syft";
|
|
tag = "v${version}";
|
|
hash = "sha256-S7PvaLjrd6W7AyCgi8yAC0kjFwVxpf/FlzyOq3yvayE=";
|
|
# populate values that require us to use git. By doing this in postFetch we
|
|
# can delete .git afterwards and maintain better reproducibility of the src.
|
|
leaveDotGit = true;
|
|
postFetch = ''
|
|
cd "$out"
|
|
git rev-parse HEAD > $out/COMMIT
|
|
# 0000-00-00T00:00:00Z
|
|
date -u -d "@$(git log -1 --pretty=%ct)" "+%Y-%m-%dT%H:%M:%SZ" > $out/SOURCE_DATE_EPOCH
|
|
find "$out" -name .git -print0 | xargs -0 rm -rf
|
|
'';
|
|
};
|
|
# hash mismatch with darwin
|
|
proxyVendor = true;
|
|
|
|
vendorHash = "sha256-JppXYoge4hK5hw2O2KSRL1n/UX/bc2LmGEzwQW6xD44=";
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
subPackages = [ "cmd/syft" ];
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X=main.version=${version}"
|
|
"-X=main.gitDescription=v${version}"
|
|
"-X=main.gitTreeState=clean"
|
|
];
|
|
|
|
postPatch = ''
|
|
# Don't check for updates.
|
|
substituteInPlace cmd/syft/internal/options/update_check.go \
|
|
--replace-fail "CheckForAppUpdate: true" "CheckForAppUpdate: false"
|
|
'';
|
|
|
|
preBuild = ''
|
|
ldflags+=" -X main.gitCommit=$(cat COMMIT)"
|
|
ldflags+=" -X main.buildDate=$(cat SOURCE_DATE_EPOCH)"
|
|
'';
|
|
|
|
# tests require a running docker instance
|
|
doCheck = false;
|
|
|
|
postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
|
|
installShellCompletion --cmd syft \
|
|
--bash <($out/bin/syft completion bash) \
|
|
--fish <($out/bin/syft completion fish) \
|
|
--zsh <($out/bin/syft completion zsh)
|
|
'';
|
|
|
|
doInstallCheck = true;
|
|
installCheckPhase = ''
|
|
runHook preInstallCheck
|
|
|
|
$out/bin/syft --help
|
|
$out/bin/syft version | grep "${version}"
|
|
|
|
runHook postInstallCheck
|
|
'';
|
|
|
|
meta = {
|
|
description = "CLI tool and library for generating a Software Bill of Materials from container images and filesystems";
|
|
homepage = "https://github.com/anchore/syft";
|
|
changelog = "https://github.com/anchore/syft/releases/tag/v${version}";
|
|
longDescription = ''
|
|
A CLI tool and Go library for generating a Software Bill of Materials
|
|
(SBOM) from container images and filesystems. Exceptional for
|
|
vulnerability detection when used with a scanner tool like Grype.
|
|
'';
|
|
license = with lib.licenses; [ asl20 ];
|
|
maintainers = with lib.maintainers; [
|
|
developer-guy
|
|
jk
|
|
kashw2
|
|
];
|
|
mainProgram = "syft";
|
|
};
|
|
}
|