646b892680
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s
71 lines
1.6 KiB
Nix
71 lines
1.6 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
autoreconfHook,
|
|
expat,
|
|
gettext,
|
|
gtk3,
|
|
libconfuse,
|
|
makeWrapper,
|
|
pcre2,
|
|
pkg-config,
|
|
vte,
|
|
nixosTests,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "tilda";
|
|
version = "2.0.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "lanoxx";
|
|
repo = "tilda";
|
|
rev = "tilda-${finalAttrs.version}";
|
|
hash = "sha256-Gseti810JwhYQSaGdE2KRRqnwNmthNBiFvXH9DyVpak=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
autoreconfHook
|
|
makeWrapper
|
|
pkg-config
|
|
];
|
|
|
|
buildInputs = [
|
|
gettext
|
|
gtk3
|
|
libconfuse
|
|
pcre2
|
|
vte
|
|
];
|
|
|
|
# ugly hack for xgettext to work during build
|
|
env.LD_LIBRARY_PATH = "${lib.getLib expat}/lib";
|
|
|
|
# with -std=c99, the build fails due to implicit function declaration errors
|
|
# for the popen() and pclose() calls in src/tilda-lock-files.c
|
|
postPatch = ''
|
|
substituteInPlace configure.ac --replace-fail -std=c99 -std=gnu99
|
|
'';
|
|
|
|
# The config locking scheme relies on the binary being called "tilda"
|
|
# (`pgrep -C tilda`), so a simple `wrapProgram` won't suffice:
|
|
postInstall = ''
|
|
mkdir $out/bin/wrapped
|
|
mv "$out/bin/tilda" "$out/bin/wrapped/tilda"
|
|
makeWrapper "$out/bin/wrapped/tilda" "$out/bin/tilda" \
|
|
--prefix XDG_DATA_DIRS : "$GSETTINGS_SCHEMAS_PATH"
|
|
'';
|
|
|
|
passthru.tests.test = nixosTests.terminal-emulators.tilda;
|
|
|
|
meta = {
|
|
homepage = "https://github.com/lanoxx/tilda/";
|
|
description = "Gtk based drop down terminal for Linux and Unix";
|
|
mainProgram = "tilda";
|
|
license = lib.licenses.gpl3Plus;
|
|
maintainers = [ ];
|
|
platforms = lib.platforms.linux;
|
|
};
|
|
})
|