646b892680
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s
85 lines
2.3 KiB
Nix
85 lines
2.3 KiB
Nix
{
|
|
bison,
|
|
fetchFromGitHub,
|
|
flex,
|
|
lib,
|
|
perl,
|
|
postgresql,
|
|
postgresqlBuildExtension,
|
|
stdenv,
|
|
}:
|
|
|
|
let
|
|
hashes = {
|
|
# Issue tracking PostgreSQL 17 support: https://github.com/apache/age/issues/2111
|
|
# "17" = "";
|
|
"16" = "sha256-sXh/vmGyYj00ALfFVdeql2DZ6nCJQDNKyNgzlOZnPAw=";
|
|
"15" = "sha256-webZWgWZGnSoXwTpk816tjbtHV1UIlXkogpBDAEL4gM=";
|
|
"14" = "sha256-jZXhcYBubpjIJ8M5JHXKV5f6VK/2BkypH3P7nLxZz3E=";
|
|
"13" = "sha256-HR6nnWt/V2a0rD5eHHUsFIZ1y7lmvLz36URt9pPJnCw=";
|
|
};
|
|
in
|
|
postgresqlBuildExtension (finalAttrs: {
|
|
pname = "age";
|
|
version = "1.5.0-rc0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "apache";
|
|
repo = "age";
|
|
tag = "PG${lib.versions.major postgresql.version}/v${
|
|
builtins.replaceStrings [ "." ] [ "_" ] finalAttrs.version
|
|
}";
|
|
hash =
|
|
hashes.${lib.versions.major postgresql.version}
|
|
or (throw "Source for Age is not available for ${postgresql.version}");
|
|
};
|
|
|
|
makeFlags = [
|
|
"BISON=${bison}/bin/bison"
|
|
"FLEX=${flex}/bin/flex"
|
|
"PERL=${perl}/bin/perl"
|
|
];
|
|
|
|
enableUpdateScript = false;
|
|
passthru.tests = stdenv.mkDerivation {
|
|
inherit (finalAttrs) version src;
|
|
|
|
pname = "age-regression";
|
|
|
|
dontConfigure = true;
|
|
|
|
buildPhase =
|
|
let
|
|
postgresqlAge = postgresql.withPackages (_: [ finalAttrs.finalPackage ]);
|
|
in
|
|
''
|
|
# The regression tests need to be run in the order specified in the Makefile.
|
|
echo -e "include Makefile\nfiles:\n\t@echo \$(REGRESS)" > Makefile.regress
|
|
REGRESS_TESTS=$(make -f Makefile.regress files)
|
|
|
|
${lib.getDev postgresql}/lib/pgxs/src/test/regress/pg_regress \
|
|
--inputdir=./ \
|
|
--bindir='${postgresqlAge}/bin' \
|
|
--encoding=UTF-8 \
|
|
--load-extension=age \
|
|
--inputdir=./regress --outputdir=./regress --temp-instance=./regress/instance \
|
|
--port=61958 --dbname=contrib_regression \
|
|
$REGRESS_TESTS
|
|
'';
|
|
|
|
installPhase = ''
|
|
touch $out
|
|
'';
|
|
};
|
|
|
|
meta = {
|
|
broken = !builtins.elem (lib.versions.major postgresql.version) (builtins.attrNames hashes);
|
|
description = "Graph database extension for PostgreSQL";
|
|
homepage = "https://age.apache.org/";
|
|
changelog = "https://github.com/apache/age/raw/v${finalAttrs.src.rev}/RELEASE";
|
|
maintainers = [ ];
|
|
platforms = postgresql.meta.platforms;
|
|
license = lib.licenses.asl20;
|
|
};
|
|
})
|