646b892680
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s
124 lines
3.0 KiB
Nix
124 lines
3.0 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
fetchpatch2,
|
|
autoreconfHook,
|
|
pkg-config,
|
|
util-linux,
|
|
hexdump,
|
|
autoSignDarwinBinariesHook,
|
|
wrapQtAppsHook ? null,
|
|
boost,
|
|
libevent,
|
|
miniupnpc,
|
|
zeromq,
|
|
zlib,
|
|
db48,
|
|
sqlite,
|
|
qrencode,
|
|
qtbase ? null,
|
|
qttools ? null,
|
|
python3,
|
|
withGui,
|
|
withWallet ? true,
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = if withGui then "elements" else "elementsd";
|
|
version = "23.2.4";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ElementsProject";
|
|
repo = "elements";
|
|
rev = "elements-${version}";
|
|
sha256 = "sha256-UNjYkEZBjGuhkwBxSkNXjBBcLQqoan/afCLhoR2lOY4=";
|
|
};
|
|
|
|
patches = [
|
|
# upnp: fix build with miniupnpc 2.2.8
|
|
(fetchpatch2 {
|
|
url = "https://github.com/bitcoin/bitcoin/commit/8acdf66540834b9f9cf28f16d389e8b6a48516d5.patch?full_index=1";
|
|
hash = "sha256-oDvHUvwAEp0LJCf6QBESn38Bu359TcPpLhvuLX3sm6M=";
|
|
})
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
autoreconfHook
|
|
pkg-config
|
|
]
|
|
++ lib.optionals stdenv.hostPlatform.isLinux [ util-linux ]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [ hexdump ]
|
|
++ lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) [
|
|
autoSignDarwinBinariesHook
|
|
]
|
|
++ lib.optionals withGui [ wrapQtAppsHook ];
|
|
|
|
buildInputs = [
|
|
boost
|
|
libevent
|
|
miniupnpc
|
|
zeromq
|
|
zlib
|
|
]
|
|
++ lib.optionals withWallet [
|
|
db48
|
|
sqlite
|
|
]
|
|
++ lib.optionals withGui [
|
|
qrencode
|
|
qtbase
|
|
qttools
|
|
];
|
|
|
|
configureFlags = [
|
|
"--with-boost-libdir=${boost.out}/lib"
|
|
"--disable-bench"
|
|
]
|
|
++ lib.optionals (!doCheck) [
|
|
"--disable-tests"
|
|
"--disable-gui-tests"
|
|
]
|
|
++ lib.optionals (!withWallet) [
|
|
"--disable-wallet"
|
|
]
|
|
++ lib.optionals withGui [
|
|
"--with-gui=qt5"
|
|
"--with-qt-bindir=${qtbase.dev}/bin:${qttools.dev}/bin"
|
|
];
|
|
|
|
# fix "Killed: 9 test/test_bitcoin"
|
|
# https://github.com/NixOS/nixpkgs/issues/179474
|
|
hardeningDisable = lib.optionals (stdenv.hostPlatform.isAarch64 && stdenv.hostPlatform.isDarwin) [
|
|
"fortify"
|
|
"stackprotector"
|
|
];
|
|
|
|
nativeCheckInputs = [ python3 ];
|
|
|
|
doCheck = true;
|
|
|
|
checkFlags = [
|
|
"LC_ALL=en_US.UTF-8"
|
|
]
|
|
# QT_PLUGIN_PATH needs to be set when executing QT, which is needed when testing Bitcoin's GUI.
|
|
# See also https://github.com/NixOS/nixpkgs/issues/24256
|
|
++ lib.optional withGui "QT_PLUGIN_PATH=${qtbase}/${qtbase.qtPluginPrefix}";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with lib; {
|
|
description = "Open Source implementation of advanced blockchain features extending the Bitcoin protocol";
|
|
longDescription = ''
|
|
The Elements blockchain platform is a collection of feature experiments and extensions to the
|
|
Bitcoin protocol. This platform enables anyone to build their own businesses or networks
|
|
pegged to Bitcoin as a sidechain or run as a standalone blockchain with arbitrary asset
|
|
tokens.
|
|
'';
|
|
homepage = "https://www.github.com/ElementsProject/elements";
|
|
maintainers = with maintainers; [ prusnak ];
|
|
license = licenses.mit;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|