646b892680
Some checks failed
Periodic Merges (6h) / master → staging-nixos (push) Failing after 12m50s
Periodic Merges (6h) / master → staging-next (push) Failing after 12m54s
Periodic Merges (24h) / merge-base(master,staging) → haskell-updates (push) Failing after 11m54s
Periodic Merges (6h) / staging-next → staging (push) Failing after 12m13s
Periodic Merges (24h) / staging-next-25.05 → staging-25.05 (push) Failing after 13m24s
Periodic Merges (24h) / release-25.05 → staging-next-25.05 (push) Failing after 14m28s
85 lines
2.4 KiB
Nix
85 lines
2.4 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchurl,
|
|
installShellFiles,
|
|
writableTmpDirAsHomeHook,
|
|
}:
|
|
let
|
|
arch =
|
|
with stdenv.hostPlatform;
|
|
if isx86_64 then
|
|
"amd64"
|
|
else if isAarch64 then
|
|
"arm64"
|
|
else if isi686 then
|
|
"386"
|
|
else if isPower64 && isLittleEndian then
|
|
"ppc64le"
|
|
else if isS390x then
|
|
"s390x"
|
|
else
|
|
throw "Unsupported arch: ${stdenv.hostPlatform.system}";
|
|
platform =
|
|
if stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64 then
|
|
"macos_arm64"
|
|
else if stdenv.hostPlatform.isDarwin then
|
|
"macos"
|
|
else
|
|
"linux_${arch}";
|
|
in
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "ibmcloud-cli";
|
|
version = "2.36.0";
|
|
|
|
src = fetchurl {
|
|
url = "https://download.clis.cloud.ibm.com/ibm-cloud-cli/${finalAttrs.version}/binaries/IBM_Cloud_CLI_${finalAttrs.version}_${platform}.tgz";
|
|
hash =
|
|
{
|
|
"x86_64-darwin" = "sha256-hIHFfUxAhpA+YIN7Bq65khFFj+3BCuYRtMq2WjQwqYQ=";
|
|
"aarch64-darwin" = "sha256-ZZ500RWagqhf63zwiQpV8y+gtCxGfbA36F97x67coUE=";
|
|
"x86_64-linux" = "sha256-+ZKlFvrDPm3ERq8/r7cjgsJWjUr8+sGFqYXdiSUPeXo=";
|
|
"aarch64-linux" = "sha256-ER/Ey3Jux3i8tC30/65awHdEd6efscUVjX/bFAk1b7c=";
|
|
"i686-linux" = "sha256-5A0kUegKVHSTZ+jRg5+07wvV4PkCvOPddvyC1ZLCbmI=";
|
|
"powerpc64le-linux" = "sha256-XcHrdA9i3Euc0yIjUtFrmIFMJi+onXRK+tHzNxmQwHg=";
|
|
"s390x-linux" = "sha256-loGQxvUqp9ngieVOVuZ6IhOKgyrVGBd+y9LdZtKEPwc=";
|
|
}
|
|
.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
installShellFiles
|
|
writableTmpDirAsHomeHook
|
|
];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
install -Dm755 ibmcloud $out/bin/ibmcloud
|
|
mkdir -p $out/share/ibmcloud
|
|
cp LICENSE NOTICE $out/share/ibmcloud
|
|
installShellCompletion --cmd ibmcloud --bash <($out/bin/ibmcloud --generate-bash-completion)
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru.updateScript = ./update.sh;
|
|
|
|
meta = {
|
|
description = "Command line client for IBM Cloud";
|
|
homepage = "https://cloud.ibm.com/docs/cli";
|
|
license = lib.licenses.asl20;
|
|
maintainers = with lib.maintainers; [ emilytrau ];
|
|
platforms = [
|
|
"x86_64-linux"
|
|
"aarch64-linux"
|
|
"i686-linux"
|
|
"powerpc64le-linux"
|
|
"s390x-linux"
|
|
]
|
|
++ lib.platforms.darwin;
|
|
sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
|
|
mainProgram = "ibmcloud";
|
|
};
|
|
})
|